뷰포트 작업시 궁금한 점

오토캐드에서는  리습이라는 것을 제공하므로서 조립식장난감을 준것입니다.
레고블록 조각의 형태는 못바꾸지만  배치하고 가지고 노는것은 아이들 마음대로 입니다.

돌드럼님도 짧은 코드를 몇번 바꾸어 보신 것으로 알고  있습니다.
자신이 손으로 하는 작업을 리습으로 옮기는 방법에 익숙해 지시면
간단한 반복 작업들은 편해집니다.

리습을 구현하는 것은 잘못된 방법을 선택하는 것이 아니면 안되는건 거의 없습니다.
손으로 작업할때  방법을 구식 코드로 구현한 것이니 참조하시기 바랍니다.

(defun c:vp_join(/ ss ent_ ent_list p_cen m_cen p_high sc n p_ce p_h ct pd_xy md_xy m_xy)
  (prompt “기준VIEWPORT창과 선택한 VIEWPORT창을 위치참조하여 동일한 줌으로 설정”)

  (command “pspace”)

  (prompt “기준 VIEWPORT를 선택:”)
  (setq ss (ssget “+.:S” ‘((0 . “VIEWPORT”))))  ; VIEWPORT 하나만 선택
  (setq ent_ (ssname ss 0))
  (setq ent_list (entget ent_))
  (setq p_cen  (cdr (assoc 10 ent_list))) ; 기준창 중심
  (setq m_cen  (cdr (assoc 12 ent_list))) ; 기준줌 중심
  (setq p_high (cdr (assoc 41 ent_list))) ; 기준창 높이
  (setq m_high (cdr (assoc 45 ent_list))) ; 기준줌 높이
  (setq sc     (/ p_high m_high))         ; 기준줌 스케일

  (prompt “동기화시킬 VIEWPORT를 선택:”)
  (setq ss (ssget ‘((0 . “VIEWPORT”))))         ; VIEWPORT 선택

  (command “mspace”)

  (setq n 0)
  (while (setq ent_ (ssname ss n))
     (setq ent_list (entget ent_))
     (setq p_ce (cdr (assoc 10 ent_list)))  ; 변경창 중심
     (setq p_h  (cdr (assoc 41 ent_list)))  ; 변경창 높이
     (setq ct   (cdr (assoc 69 ent_list)))  ; 변경창 번호

     (setq pd_xy (mapcar ‘- p_ce p_cen))    ; 기준창과 변경창 중심거리
     (setq md_xy (mapcar ‘(lambda (x) (/ x sc)) pd_xy ) ) ; 창의거리를 실제거리로 환산
     (setq m_xy  (mapcar ‘+ m_cen md_xy))    ; 화면중심
     (setq m_h   (/ p_h sc) )                ; 창의 높이를 실제높이로 환산

     (setvar “cvport” ct)  ; 변경창으로 이동
     (command “zoom” “c” m_xy m_h)  ;중심 이동 기준줌크기로 변경

     (setq n (1+ n))
  );while

  (command “pspace”)

);defun